SannyBuilder.com Forums

не сбивай парня. Еще как обойтись. Вот на скорую руку написал синхронизатор времени. Устанавливает часы, минуты и день недели на реальные.

{$CLEO}
if
    0AA2: 0@ = load_library "kernel32.dll" // IF and SET
then
    if
        0AA4: 1@ = get_proc_address "GetLocalTime" library 0@ // IF and SET
    then
        0AB1: call_scm_func @__LabelToOffset 1 @SYSTEMTIME_struct 2@    //получаем ссылку на структуру
        while true
            wait 250
            0AA5: call 1@ num_params 1 pop 0 2@    //заполняем структуру текущим временем
            0085: 12@ = 2@
            for 11@ = 0 to 7                       //считываем данные из струкутуры в массив 3@ - 10@
                0A8D: 3@(11@,8i) = read_memory 12@ size 2 virtual_protect 0 
                12@ += 2         
            end
            //Записываем полученные данные по соотв. адресам памяти
            00C0: set_current_time_hours_to 7@ minutes_to 8@
            5@ += 1
            0A8C: write_memory 0xB7014E size 1 value 5@ virtual_protect 0             //день недели
        end
    end
    0AA3: free_library 0@
end
0a93:

:SYSTEMTIME_struct   //sizeof = 0x10
hex
00 00 //wYear           +0x0
00 00 //wMonth          +0x2
00 00 //wDayOfWeek      +0x4
00 00 //wDay            +0x6
00 00 //wHour           +0x8
00 00 //wMinute         +0xA
00 00 //wSecond         +0xC
00 00 //wMilliseconds   +0xE
end

:__LabelToOffset
if
    0@ == 0
then
    0AB2: ret 1 0
end
0A9F: 1@ = current_thread_pointer
1@ += 0x10 
0A8D: 1@ = read_memory 1@ size 4 virtual_protect 0 // baseIP
0062: 1@ -= 0@ // label address
0AB2: ret 1 1@

Alien, спасибо!

А cleo-то установлен?
Какой версии?

Это потому, что kernel32.dll не загружается. У меня тоже не пашет.
@Alien - какой путь нужно прописывать?

да нет, всё равно. Может, версия не подходит? 6.1.7600.16385

Теперь работает. А как текст вывести?

Кстати, вместо 

[b]00C0: set_current_time_hours_to 7@ minutes_to 8@[/b]

лучше поставить

0A8C: write_memory 11993427 size 1 value 7@ virtual_protect 0 
0A8C: write_memory 11993426 size 1 value 8@ virtual_protect 0

А то получаются казусы с погодой(как со стандартным читом).